250ぐらいのhtmlがあります。

Windows 前提の回答です。違いましたらすいません。

下記を拡張子 ".VBS" にして適当なファイル名で保存します。

挿入する内容を記載したファイルを用意し、ファイルパスを4行目の INSERT_FILE に書きます。

変換対象のHTML ファイルを置いているフォルダ位置を5行目の HTML_FOLDER に書きます。

Option Explicit

'---------------------------------------------------------------------
Const INSERT_FILE = "C:\Data\insert.txt" '---  挿入するファイル名の指定
Const HTML_FOLDER = "C:\HTMLFiles"       '---  変換対象ファイルのフォルダを指定
Const KEY_WORD    = "</div>"             '---  検索するタグの指定
Const KEY_COUNT   = 13                   '---  検索後の置換して位置
'---------------------------------------------------------------------

Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

If fso.FileExists( INSERT_FILE ) = False Then
    WScript.Echo "挿入データファイル【" & INSERT_FILE & "】がありません: "
    WScript.Quit
End If
Dim insData
insData = fso.OpenTextFile( INSERT_FILE ).ReadAll()

Dim fCount
Dim hFile
Dim txtData
Dim pos
'--- 指定フォルダ内の HTML ファイルを処理
For Each hFile In fso.GetFolder( HTML_FOLDER ).Files
    '--- 拡張子のチェック ---
    If UCase( fso.GetExtensionName( hFile ) ) = "HTML" Then
        txtData = fso.OpenTextFile( hFile.Path ).ReadAll()
        pos = getPos( txtData )
        If pos > 0 Then
            If Mid( txtData, pos + 1, 1 ) = Chr(10) Or  Mid( txtData, pos + 1, 1 ) = Chr(13) Then
                txtData = Left( txtData, pos ) & vbNewLine & insData & Mid( txtData, pos + 1 )
            Else
                txtData = Left( txtData, pos ) & vbNewLine & insData & vbNewLine & Mid( txtData, pos + 1 )
            End If
    '--- ファイルをバックアップして更新 ---
            fso.CopyFile hFile.Path, hFile.Path & ".bak"  '--- バックアップが不要な場合はこの行を削除
            fso.CreateTextFile( hFile.Path, True ).Write txtData
            fCount = fCount + 1
        Else
    '--- タグが指定回数ない
            WScript.Echo hFile.Name & "：指定回数の " & KEY_WORD & " がありません。"
        End If
    End If
Next
WScript.Echo fCount & " 個のファイルを処理しました。"

'---------------------------------------------------------------------
' 挿入位置の検索
'---------------------------------------------------------------------
Function getPos( txtData )
'---------------------------------------------------------------------
    Dim sPos
    Dim dCount
    sPos= InStr( txtData, KEY_WORD )
    Do While sPos > 0
        dCount = dCount + 1
        If dCount = KEY_COUNT Then
            getPos = sPos + Len( KEY_WORD ) - 1
            Exit Function
        End If
        sPos = InStr( sPos+ 1, txtData, KEY_WORD )
    Loop
End Function

修正・保存したファイルを実行（ダブルクリック）でご希望の処理が実行されないでしょうか。

http://www.whitire.com/vbs/

不明な点はコメントで補足します。