Accessのデータベースファイルを64bit版のofficeで開いた際、32bit版で使用できていた機能（ファイル取り込みの際に「参照」等のボタンを押すとウインドウが開く）を使えるようにしたいです

参考にしているサイトで構造体の定義が違いますね。
aは、「lpstrCustomFilter As Long」
bは、「lpstrCustomFilter As String」

aの定義を使用していて「ofn.lpstrCustomFilter　= 0」はOKだけど、
bの定義を使用していて「ofn.lpstrCustomFilter　= 0」だと、GetOpenFileNameAPIがスルーされます。
bの定義を使用しているなら、
ofn.lpstrCustomFilter　= String(512,vbNullChar)
ofn.nMaxCustFilter = Len(ofn.lpstrCustomFilter)
などにすれば動くのでは。

そのあたりをチェックしてもダメなようなら、一番シンプルなコードでテストしてみては？
新規のmdb（accdb）に標準モジュールを1つ作ってベーシックなコードでテスト。
例えば、次のようなコードを張り付けて、イミディエイトウインドウに　「？ GetOpenFileName」と入力してリターンがあるかとか。　私の環境では問題なく動作しました。

Private Declare PtrSafe Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (pOpenFileName As OPENFILENAME) As Long
Private Type OPENFILENAME
lStructSize As Long
hwndOwner As LongPtr
hInstance As LongPtr
lpstrFilter As String
lpstrCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
lpstrFile As String
nMaxFile As Long
lpstrFileTitle As String
nMaxFileTitle As Long
lpstrInitialDir As String
lpstrTitle As String
Flags As Long
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String
lCustData As LongPtr
lpfnHook As LongPtr
lpTemplateName As String
End Type

Private Const OFN_EXPLORER = &H80000

Public Function GetFileName() As String

Dim ofn As OPENFILENAME
Dim lngRet As Long

With ofn
.hwndOwner = Application.hWndAccessApp
.hInstance = 0
.lpstrFilter = "全てのファイル (*.*)" & String(1, vbNullChar) & "*.*" & String(2, vbNullChar)
.lpstrCustomFilter = String(512, vbNullChar)
.nMaxCustFilter = Len(.lpstrCustomFilter)
.nFilterIndex = 1
.lpstrFile = String(512, vbNullChar)
.nMaxFile = 512
.lpstrFileTitle = String(512, vbNullChar)
.nMaxFileTitle = 512
.lpstrInitialDir = String(1, vbNullChar)
.lpstrTitle = String(1, vbNullChar)
.nFileOffset = 0
.nFileExtension = 0
.lpstrDefExt = String(1, vbNullChar)
.lCustData = 0
.lpfnHook = 0
.lpTemplateName = 0
.Flags = OFN_EXPLORER
.lStructSize = Len(ofn)

lngRet = GetOpenFileName(ofn)

GetFileName = Left(.lpstrFile, InStr(.lpstrFile, vbNullChar) - 1)
End With

End Function